vb中如何实现查找文件

楼上的编程真长.
你也可以使用控件组合进行磁盘文件查找.
如果是小型软件我建议你这样做.为因很简单速试同样不慢
使用控件有
DriveListBox 控件
DirListBox 控件
FileListBox 控件
以上控件如无需用户操作可将Visible 属性设置为FALSE
编程思路如下
首先确定查先路径.也就是对以上三个控件相应属性进行设置.
最后例用FOR 或WHILE循环.过滤FILELISTBOX控件的List属性.
以上思路仅供参考

'模块部分
Option Explicit

Declare Function MoveWindow Lib "user32" _
(ByVal hwnd As Long, _
ByVal x As Long, ByVal y As Long, _
ByVal nWidth As Long, ByVal nHeight As Long, _
ByVal bRepaint As Long) As Long

Declare Function SendMessage Lib "user32" Alias "SendMessageA" _
(ByVal hwnd As Long, ByVal wMsg As Long, _
ByVal wParam As Long, lParam As Any) As Long

Public Const LB_INITSTORAGE = &H1A8

Public Const LB_ADDSTRING = &H180

Public Const WM_SETREDRAW = &HB
Public Const WM_VSCROLL = &H115
Public Const SB_BOTTOM = 7

Declare Function GetLogicalDrives Lib "kernel32" () As Long

Declare Function FindFirstFile Lib "kernel32" Alias "FindFirstFileA" _
(ByVal lpFileName As String, lpFindFileData As WIN32_FIND_DATA) As Long

Public Const INVALID_HANDLE_VALUE = -1

Declare Function FindNextFile Lib "kernel32" Alias "FindNextFileA" _
(ByVal hFindFile As Long, lpFindFileData As WIN32_FIND_DATA) As Long

Declare Function FindClose Lib "kernel32" (ByVal hFindFile As Long) As Long

Type FILETIME
dwLowDateTime As Long
dwHighDateTime As Long
End Type

Public Const MaxLFNPath = 260

Type WIN32_FIND_DATA
dwFileAttributes As Long
ftCreationTime As FILETIME
ftLastAccessTime As FILETIME
ftLastWriteTime As FILETIME
nFileSizeHigh As Long
nFileSizeLow As Long
dwReserved0 As Long
dwReserved1 As Long
cFileName As String * MaxLFNPath
cShortFileName As String * 14
End Type

'窗体部分

'自行添加所需控件

Option Explicit

Dim PicHeight%, hLB&, FileSpec$, UseFileSpec%
Dim TotalDirs%, TotalFiles%, Running%

Dim WFD As WIN32_FIND_DATA, hItem&, hFile&

Const vbBackslash = "\"
Const vbAllFiles = "*.*"
Const vbKeyDot = 46

Private Sub Form_Load()
ScaleMode = vbPixels
PicHeight% = Picture1.Height
hLB& = List1.hwnd
SendMessage hLB&, LB_INITSTORAGE, 30000&, ByVal 30000& * 200
Move (Screen.Width - Width) * 0.5, (Screen.Height - Height) * 0.5
End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
If KeyCode = vbKeyEscape And Running% Then Running% = False
End Sub

Private Sub Form_Resize()
MoveWindow hLB&, 0, 0, ScaleWidth, ScaleHeight - PicHeight%, True
End Sub

Private Sub Form_Unload(Cancel As Integer)
Set Form1 = Nothing
End
End Sub

Private Sub List1_Click()

End Sub

Private Sub mnuFindFiles_Click()

If Running% Then: Running% = False: Exit Sub

Dim drvbitmask&, maxpwr%, pwr%
On Error Resume Next

FileSpec$ = InputBox("模糊查找文件:" & vbCrLf & vbCrLf & _
"本例将从A：开始查找并继续，直到查" & _
"找完所有有效驱动器。在查找过程中可以随时终止。 " & _
"支持通配符 “*” 与 “?”，如*.doc。" & vbCrLf & _
"")

If Len(FileSpec$) = 0 Then Exit Sub

MousePointer = 11
Running% = True
UseFileSpec% = True
mnuFindFiles.Caption = "停止(&p)"
mnuFolderInfo.Enabled = False
List1.Clear

drvbitmask& = GetLogicalDrives()
If drvbitmask& Then

maxpwr% = Int(Log(drvbitmask&) / Log(2))
For pwr% = 0 To maxpwr%
If Running% And (2 ^ pwr% And drvbitmask&) Then _
Call SearchDirs(Chr$(vbKeyA + pwr%) & ":\")
Next
End If

Running% = False
UseFileSpec% = False
mnuFindFiles.Caption = "查找文件(&s)"
mnuFolderInfo.Enabled = True
MousePointer = 0

Picture1.Cls
Picture1.Print "查找到的文件数： " & List1.ListCount & " 本次查找的匹配条件： " & """" & FileSpec$ & """"
Beep

End Sub

Private Sub mnuFolderInfo_Click()

If Running% Then: Running% = False: Exit Sub

Dim searchpath$
On Error Resume Next

searchpath$ = InputBox("查找目标（含驱动器，如：c:\winnt）:", "指定文件夹信息", "C:\")
If Len(searchpath$) < 2 Then Exit Sub
If Mid$(searchpath$, 2, 1) <> ":" Then Exit Sub
If Right$(searchpath$, 1) <> vbBackslash Then searchpath$ = searchpath$ & vbBackslash
If FindClose(FindFirstFile(searchpath$ & vbAllFiles, WFD)) = False Then
MsgBox searchpath$, vbInformation, "Path is invalid": Exit Sub
End If

MousePointer = 11
Running% = True
mnuFolderInfo.Caption = "停止(&S)"
mnuFindFiles.Enabled = False
List1.Clear

TotalDirs% = 0
TotalFiles% = 0
Call SearchDirs(searchpath$)

Running% = False
mnuFolderInfo.Caption = "设置文件夹(&F)..."
mnuFindFiles.Enabled = True
Picture1.Cls
MousePointer = 0

MsgBox "文件夹: " & TotalDirs% & vbCrLf & _
"文件: " & TotalFiles%, , _
"文件夹设置: " & searchpath$

End Sub

Private Sub SearchDirs(curpath$)

Dim dirs%, dirbuf$(), i%

Picture1.Cls
Picture1.Print "Searching " & curpath$

DoEvents
If Not Running% Then Exit Sub

hItem& = FindFirstFile(curpath$ & vbAllFiles, WFD)
If hItem& <> INVALID_HANDLE_VALUE Then

Do
If (WFD.dwFileAttributes And vbDirectory) Then

If Asc(WFD.cFileName) <> vbKeyDot Then
TotalDirs% = TotalDirs% + 1
If (dirs% Mod 10) = 0 Then ReDim Preserve dirbuf$(dirs% + 10)
dirs% = dirs% + 1
dirbuf$(dirs%) = Left$(WFD.cFileName, InStr(WFD.cFileName, vbNullChar) - 1)
End If
ElseIf Not UseFileSpec% Then
TotalFiles% = TotalFiles% + 1
End If

Loop While FindNextFile(hItem&, WFD)

Call FindClose(hItem&)

End If
If UseFileSpec% Then
SendMessage hLB&, WM_SETREDRAW, 0, 0
Call SearchFileSpec(curpath$)
SendMessage hLB&, WM_VSCROLL, SB_BOTTOM, 0
SendMessage hLB&, WM_SETREDRAW, 1, 0
End If

For i% = 1 To dirs%: SearchDirs curpath$ & dirbuf$(i%) & vbBackslash: Next i%

End Sub

Private Sub SearchFileSpec(curpath$)

hFile& = FindFirstFile(curpath$ & FileSpec$, WFD)
If hFile& <> INVALID_HANDLE_VALUE Then

Do
DoEvents
If Not Running% Then Exit Sub

SendMessage hLB&, LB_ADDSTRING, 0, _
ByVal curpath$ & Left$(WFD.cFileName, InStr(WFD.cFileName, vbNullChar) - 1)

Loop While FindNextFile(hFile&, WFD)

Call FindClose(hFile&)

End If

End Sub

我这里有,留下邮箱