WOW法师实用宏

顺序是蛋壳 冰枪 闪现 拉到卡怪点后冰箱 拉怪时候注意蛋壳 天赋里面有个 冰霜效果有几率将怪冻结的 要点了 然后怪跟的近了 多了冰环下 继续拉 卡怪点隐身 隐身消失前补蛋壳 冰环 闪现 弄好快捷键不用宏 因为很多随机处理的情况 cd是自己看的
宏怎么做 一句话说不清楚 我发你些东西 看看吧
/TBC宏命令上手教程

简单的说, 宏就是创建一连串的命令集，通过鼠标点击或按下键盘某个按键就让电脑自动执行这一系列命令。
在进入游戏之前，特别是用全屏模式进行游戏的，需要掌握一些基本知识。曾经在网吧看过一位玩家做宏，他把网站上别人写好的宏用一张纸抄写下来，然后进入游戏宏设置中一字字敲下，途中发现某些宏用不了，又退出游戏打开网站查询，拿笔记在纸上再次进入游戏尝试。。。。。。
看到这里可能玩转电脑的高手们会笑，但确实是这样，不是亲眼目睹我也不敢相信还有人用这样原始的做宏方法。
所以，首先有必要说明在操作系统平台下或游戏中，当不能使用鼠标右键弹出选项菜单时几个键盘组合键功能：
1.“Ctrl”控制键+“C”键---复制
2.“Ctrl”控制键+“V”键---粘贴
3.“Ctrl”控制键+“X”键---剪切
4.“Ctrl”控制键+“A”键---全选
5.“Windows”键（即操作系统图标的按键一般位于“Ctrl”控制键与“Alt”换档键之间）+“D”键---最小化所有任务到任务栏并显示桌面。
6.“Windows”键+“Tab"制表键---在任务栏打开的各项任务间进行切换。

下面让我们在游戏中一步步设置宏命令：

一.进入游戏后按“Esc”键或点主菜单图标可打开游戏主选单，点选“宏命令设置”。
当然亦可敲下“回车”键在对话框中输入/MACRO也能打开宏命令设置界面。

二.打开宏命令设置面板后，如果想建立的是角色专用宏，还必须先点上方“通用宏”旁边的角色“专用宏”，在选“新建”后打开建立新宏的面板：

三.输入宏的名字，选取一个宏图标后点“确定”，就建立了一个新宏。
这里需要注意的是，当选取的是第一个“？”号形的图标时，该宏图标将以宏内容中输入的法术技能图标显示。

四.点击宏命令主面板上方中的宏图标，在下方输入宏内容，然后将这个宏图标拖放到快捷技能栏里，就能使用了。

五.宏命令内容的输入:

1. 宏的内容中每项命令以分行的形式隔开，这里说的分行并不是说宏面板上写到一定数量后顺列到下行，而是指在宏内容中敲下“回车”键后所进行的分行。在中文版的WOW中不论是输入中文或英文命令，只要输入字符正确均能使用，一般在宏中使用英文不必区分大小写。想把某个技能写进宏中，只需打开技能面板后点击宏内容中想要输入的地方，然后按住“Shift”上档键同时点击法术技能图标就可以；想把背包中某件物品名写进宏中亦是同理。
例：暗夜精灵在喝水的同时施放影遁（宏中的斜杠/+“use"+空格+物品名是物品使用宏的一般格式，当然后面的物品名也可换成魔法面包等等）
/坐下
/use 魔法晶水
/施放 影遁（种族特长）

2.行为命令宏内容的一般书写格式：斜杠/+空格键+技能名（或行为内容）
书写技能的时候若在后面加上（等级X），将使用特定等级的法术，仅书写技能名时默认使用最高等级的法术
例：猎人在标记敌对目标的同时喊话提醒队友
/大喊 我已进行标记大家集中火力消灭他！
/施放 猎人印记
在写宏中大家以后还会经常用到“%t”这个字符，“%t”表示你当前目标的名字。
例：猎人在标记一只野猪的同时喊话提醒队友
/大喊 我已标记 %t 大家集中火力消灭他！
/施放 猎人印记

3.在TBC中当某个技能带有公共CD时（近战一般是1秒,法系1.5秒），也就是施放某个法术时其他大部分技能图标也会跟着绕一圈的时间，这种带有公共CD的技能在宏内容中仅仅依靠简单分行顺序施放的方法是不行的。
例如：战士想通过连续按宏在压制不能使用时施放英勇打击（在TBC的宏规则中当“压制”处于冷却时间或不可用导致施放失败后，第二次按该宏就会继续重复运行第一行的“/施放 压制”，不能自动跳过尚未放出的技能转到第二行宏命令）
所以，下面这个宏是失败的：
/施放 压制
/施放 英勇打击
但是，仍可通过简单分行顺序施放编在同个宏中的技能命令，条件是“技能为瞬发并且这几个技能间不同享公共CD”，比如冷血和伏击 。

例：战士在施放血性狂暴，当血性狂暴技能尚未冷却时再次运行该宏就施放战斗怒吼（“cast”等于“施放”）
/cast 血性狂暴
/cast 战斗怒吼
另外,虽然同享公共CD，但释放条件不同的技能仍然可用各种宏函数串接起来顺序施放，在以后的教程中会谈到这类宏内容的设置。

4.选择和切换目标宏，这在游戏中是较为频繁使用的！
目标选择宏一般书写格式为：宏函数+空格+目标内容
例：不论当前目标是什么或者没有目标，立即切换到指定目标加BUFF
/target 角色名字
/cast 奥术智慧（等级3）

一些常用的目标选择宏函数有：
target 选定目标，例如 /target 冬狼
targettarget 目标的目标，例如 /target targettarget 指目标立即切换到当前目标的目标
pet 宠物，例如 /click [pet] PetActionButton1 指的是使用宠物技能栏中第一个技能
partyX表示第X个小队队友，例如party1，party2。。。。。。
partypetX 表示第X个小队队友的宠物，例如partypetX1，partypetX2。。。。。。
raidX 表示第X个团队队友，例如raid1，raid2。。。。。。
/cleartarget 清除当前目标
/targetlasttarget 选定上一个目标
/startattack 对当前目标进行连续性攻击直到目标死去或消失，这个宏对近战和带宠职业非常有用！

5.其它一些常用宏命令：
/AFK 暂离，当然也可以输入中文 /暂离
/DND 请勿打扰，还可进行自动回复，例如 /DND 我有事离开一下，待会再谈！
/1 将聊天频道切换为综合频道
/6 将聊天频道切换为寻求组队频道
例：需要离开电脑一段时间，想把信息传到综合和寻求组队频道，同时令角色马上处于暂离状态并自动回复宏
/1 我的朋友们注意啦，我有事要离开一会，等会来了再找大伙聊哈
/6 我的朋友们注意啦，我有事要离开一会，等会来了再找大伙聊哈
/DND 我有事离开一下，待会再谈！
/AFK
大家也可以在游戏中查询命令：打开对话框后键入斜杠/，再输入中文单字或英文字母，然后陆续按下“Tab”制表键，会在对话框中分别列出以这个字开头的所有命令。
例如键入字母“/a ”后按几次“Tab”制表键，会依次显示出以字母“a”开头的/assist，/afk，/announce，/ann，/agree等等命令！

6.用操作系统中的“记事本”程序，打开游戏目录中宏的记录文件可直接对宏命令进行编辑。
通用宏文件夹位置： World of Warcraft → WTF → Account → 以您游戏帐号命名的文件夹 → macros-cache.txt
角色专用宏文件夹位置：World of Warcraft → WTF → Account → 以您游戏帐号命名的文件夹 → 以您游戏角色所在服务器命名的文件夹 → 以您游戏角色名称命名的文件夹 → macros-cache.txt

TBC宏命令实战教程

宏教程与写其他心情类啦副本攻略类的文章比较，相对来说较难下笔。看过许多关于宏方面的资料，大多显得杂乱无章且多数为外文的生硬翻译。
本文尽量用通俗易懂的文字来描叙，由于宏的涉及较为复杂，我也只能尽力而为啦！说实在的，写这篇东西感到前所未有的吃力，或是在下才疏学浅的缘故吧！
闲话叙过，切入正题。

一. 物品使用类宏命令

1.使用装备：/equipslot

例：一键换装宏，下宏的中段数字表示装备部位的编号

/equipslot 16 大元帅的长刀
/equipslot 13 黑手饰物
/equipslot 15 坚定力量披风

2.使用物品：/use

例：法师的一键补充宏，按排列先后顺序使用下列物品

#showtooltip 魔法晶水
/use 魔法晶水
/use 魔法肉桂面包
/use [combat]法力红宝石
/use [combat]法力黄水晶
/use [combat]法力翡翠
/use [combat]法力玛瑙
/use [combat]特效治疗石

注：#showtooltip------指的是这个宏图标显示为该物品或技能；

[combat]------条件宏，这里指的是战斗状态，下文中会详细介绍条件宏的使用。

3.某些特殊道具宏的书写格式

例1：使用饰品
/cast 6级雷矛勋章

例2：使用坐骑
/use 黑色军用机械陆行鸟

二.条件判断类宏命令

1.一般书写格式为：斜杠/命令 + 空格 +[条件参数] 行为名称

例：一键回蓝，优先喝水，当处于战斗中时使用法力红宝石
/use 魔法晶水
/use [combat]法力红宝石

2.多个判断条件的宏命令，每行中各技能以分号隔开，一般书写格式为：

斜杠/命令 + 空格 +[条件1，条件2。。。] 行为名称1；[条件3，条件4。。。] 行为名称2

例：当目标为敌对时使用“变形术”，当不在战斗中并且目标不是敌对时施放“钓鱼”
/cast [harm]变形术;[nocombat,noharm]钓鱼

3.大多条件判断宏的书写都可以在前面加上“no”，使之判断条件恰好相反

三.上篇《燃烧的远征版宏命令入门教程》中提到，TBC版单个宏命令中多个同享公共CD的技能不能通过简单分行书写排列施放了，但仍能用一些宏函数将其串接起来使用，下面让我们分析下这个宏：

/施放 致死打击
/施放 英勇打击

这个宏的初衷是希望通过连续点击一个按键就施放“致死打击”或“英勇打击”，但是由于TBC版宏特性改变，
宏首先会检测第一行命令，当条件不满足时这个宏就停止运行了，也就是说当“致死打击”不能用的时候，
不会自动跳到下行施放出“英勇打击”；
即使“致死打击”成功施放，第二次再运行该宏时仍然先检测第一行命令，这样的话上面这个宏其实只能施放“致死打击”单技能，后面的“英勇打击”永远打不出。

那么，还有什么办法能在同个宏中施放多个同享公共CD的技能呢？
这里可用到前面第二大条叙述的条件判断宏来串接各技能；
还有就是使用到TBC版宏命令中的新特征，/castsequence
也就是按顺序施放一组事先设定好的法术！值得注意的是序列中一个法术施放失败，后面的法术就不会被施放。
所以这类命令通常与宏的重置命令结合使用。

例：战士希望通过连续点击一个按键顺序施放“致死打击”和“英勇打击”
# show 致死打击
/stopcasting
/castsequence reset=6/target/combat 致死打击,英勇打击
/startattack

详细解释上面这个宏：

# show 致死打击------建立该宏时选择的是个“？”号型图标，这里的作用就是让宏图标中优先显示“致死打击”
/stopcasting------立即打断当前正在进行的法术或动作
/castsequence reset=6/target/combat 致死打击，英勇打击------/castsequence即循序施放多个技能的斜杠命令；reset=6指6秒后重置该宏，当然这里表示时间的数字可以自定；/target指切换目标时重置该宏；/combat指战斗开始时重置该宏； 最后面的技能名就是顺序施放的法术，技能间用逗号隔开
/startattack------连续攻击当前敌对目标，直到该目标死去或消失！

四.建宏时需要注意的事项

1.在建立宏命令时，如果是职业专用宏，最好选择写进角色专用宏里，因为宏数量是有限的，避免占用多个通用宏的位置！

2.若无必要，最好尝试自己编写宏命令，别懒到总是复制人家写好的来用。
在编写的过程中相信你会找到一些乐趣的！
况且简单的复制人家写好的宏命令，在实际使用中经常会遇到这样那样的问题。

3.使用操作系统中的“记事本”程序，打开游戏目录中宏的记录文件可直接对宏命令进行编辑。
通用宏文件夹位置： World of Warcraft → WTF → Account → 以您游戏帐号命名的文件夹 → macros-cache.txt角色专用宏文件夹位置：World of Warcraft → WTF → Account → 以您游戏帐号命名的文件夹 → 以您游戏角色所在服务器命名的文件夹 → 以您游戏角色名称命名的文件夹 → macros-cache.txt

4.新建宏的时候多使用那个“？”号型图标；
写宏的同时在内容中加一行“#showtooltip 技能名”，宏技能图标就会以该法术图标显示，很方便

5.写宏的时候千万别乱添符号
见过许多习惯于写代码的朋友们，往往喜欢在每行结尾加个；号

例：书写错误的法师多用途宏
#showtooltip 寒冰箭
/use [harm]赞达拉英雄护符；
/cast [modifier:alt,harm]寒冰箭(等级 1);[harm]寒冰箭;[modifier:alt]冰甲术;[modifier:ctrl]法师护甲;[nocombat,noharm]造水术；

这个宏本来是功能强大的，唯一的错误就是在每行后面多添加了个；号，导致下行的寒冰箭啦，造水术啦统统放不出！

五.我自己写的几组通用宏

提供给大家参考，这些宏的具体作用大家就自己去分析吧

例：战士宏

/stopcasting
/cast [stance:1,combat,harm]反击风暴
/cast [stance:2,combat,harm]盾墙
/cast [stance:3,combat,harm]鲁莽

例：法师宏

#showtooltip 冰霜新星
/stopcasting
/cast [noharm,nocombat,modifier:ctrl]奥术光辉;[modifier:alt,noharm,nocombat]奥术智慧;[nocombat,noharm]造食术;
/cast 冰霜新星

例：一键附魔，分解，叫卖

/cast [button:2]分解; 附魔
/1 附魔★披风5全抗★衣服100生命/全属性+3★手套7敏/剥皮/采矿★鞋7耐/7敏/移动速度★手腕9耐★武器25敏/冰寒/+7冰法伤害/屠魔/十字军
/2 附魔★披风5全抗★衣服100生命/全属性+3★手套7敏/剥皮/采矿★鞋7耐/7敏/移动速度★手腕9耐★武器25敏/冰寒/+7冰法伤害/屠魔/十字军
/6 附魔★披风5全抗★衣服100生命/全属性+3★手套7敏/剥皮/采矿★鞋7耐/7敏/移动速度★手腕9耐★武器25敏/冰寒/+7冰法伤害/屠魔/十字军

TBC宏命令高级教程

一.通用宏
例1：一键回血，要改为一键回蓝的话大家把物品名相对改下即可，当然亦可增添几行命令
#showtooltip 魔法肉桂面包
/use 魔法肉桂面包
/use 奥特兰克冷酪
/use [combat]厚符文布绷带
/use [combat]符文布绷带
/use [combat]优质治疗药膏
/use [combat]强效治疗药水
/use [combat]丝质绷带

例2：右键点击是在小地图上显示附近矿物图标，左键点则打开熔炼面板
#showtooltip 熔炼
/cast [button:2]寻找矿物;熔炼
例3：饰品宏，左键和右键点击分别使用装备在身上的不同饰品
#showtooltip 6级雷矛勋章
/stopcasting
/cast [button:2] 6级雷矛勋章; 赞达拉英雄护符

二.战士宏

例1：宏显示为冲锋的技能图标，当前目标为敌对且未处于战斗中时冲锋，否则施放挫志怒吼
# show 冲锋
/stopcasting
/cast [harm,nocombat]冲锋
/cast 挫志怒吼

例2：这个宏就不必解释了吧，战士们一看就会明白
/stopcasting
/cast [stance:1,combat,harm]反击风暴
/cast [stance:2,combat,harm]盾墙
/cast [stance:3,combat,harm]鲁莽

例3：宏显示为斩杀的技能图标，当处于战斗姿态或狂暴姿态，目标为敌对并且在战斗中时使用斩杀；当处于防御姿态，目标为敌对并且在战斗中时使用盾击；当前面的条件都不成立时运行该宏就是召唤坐骑！
# show 斩杀
# show 盾击
/stopcasting
/cast [combat,harm,stance:1]斩杀
/cast [combat,harm,stance:3]斩杀
/cast [combat,harm,stance:2]盾击
/use 黑色军用战马缰绳

三.法师宏

例1：此宏较为复杂，具体作用大家就自己分析吧，若能熟练编写该类宏命令一定能使您操作角色更为简便！
#showtooltip 寒冰箭
/use [harm]赞达拉英雄护符
/cast [modifier:alt,harm]火球术;[harm]寒冰箭;[modifier:alt]冰甲术;[modifier:ctrl]法师护甲;[nocombat,noharm]造水术
/stopmacro [target=pettarget, exists]
/petattack
/click [pet] PetActionButton1

例2：开启或关闭冰箱宏，若冰箱技能尚未冷却时则使用治疗药水
#showtooltip 寒冰屏障
/stopcasting
/cancelAura 寒冰屏障
/cast 寒冰屏障
/use 强效治疗药水
例3：要是宠物存在，使用宠物快捷栏上的第8个技能（我的宝宝第8个技能为被动状态，当然大家可以自己设置）
也就是宝宝立即处于被动状态停止攻击；若当前目标为敌对时则对其施放变形术；当前面的条件均未成立，目标不是敌对且不在战斗中时施放钓鱼。
#showtooltip 变形术
/click [pet] PetActionButton8
/cast [harm]变形术;[nocombat,noharm]钓鱼

四.牧师宏

例1：当鼠标指向的目标或当前目标是友方且未死亡，使用驱散；当鼠标指向的目标或当前目标是敌对且未死亡，使用暗言术：痛；当没有目标且鼠标并未指向任何目标时对自己使用驱散！（前提是界面设置中的自我施法必须启用）
# show 暗言术：痛
/cast [target=mouseover,exists,help,nodead] 驱散魔法; [target=mouseover,exists,harm,nodead] 暗言术：痛; [help,nodead] 驱散魔法; [harm,nodead] 暗言术：痛; [target=player] 驱散魔法

例2：当目标敌对时施放暗言术：痛；当目标友善时施放真言术：盾。并且右键点击时都是对自己施放法术。
# show 真言术：盾
/cast [button:2, target=player] 真言术：盾; [help] 真言术：盾; 暗言术：痛

例3：成功复活后才通知，当暗影形态或战斗中或目标敌对或目标未死亡时，不进行动作；否则施放复活术，并通知正在复活的目标名字。这个宏可避免以前的复活宏因为复活失败却仍然喊话的尴尬。
# show 复活术
/stopmacro [stance:1/combat]
/cast 复活术
/stopmacro [nohelp/nodead]
/大喊 %t起来吧，我的勇士！
/团队 我已复活%t

举个例子,你模仿就是了,
例如冰蛋了就喝水
/cast 寒冰护体
/use 水名字

这里CAST 是用技能前要打的标志,USE 是用物品的,我FS 就有个 冰加速+SP强化的宏
/cast 寒冰血脉
/use 妖术头颅

因为宏的动作基本都是同时进行的而法术又有公共CD,所以不可能写个宏可以自动进行两个法术技能

但有些不用公共CD 的技能如 寒冰加速,气定,
奥术强化,可以和其他技能写一起,如
/cast 寒冰血脉
/cast 暴风雪

大致的意思就是这样,宏的 功能很强大,自己琢磨才有意思

- -!你还要反应么还要操作么？你用这种宏打起来到时候比谁都容易死。作为法师就要知道如何取舍CD技能时间，即便是1.5秒的公共CD。

第一个回答还真雷，估计他自己都不知道里面是什么内容。

目前的话我知道的施放技能宏分2种，一种是以CAST（也就是施放）开头另外一种是CASTSEQUENCE（这个是顺序施放）开头。

如果以寒冰箭和冰枪为例子：
/cast 寒冰箭
那么按下去就打出顶级寒冰箭，因为没有级别所以自动选择最高级。

如果是要先丢寒冰箭再丢冰枪:
/castsequence reset=3 寒冰箭,冰枪术
那么你按第一下就是放寒冰箭，寒冰箭施放完以后再按一下就是冰枪。RESET是个循环重置参数，表示3秒后重置该宏，否则你将一直卡在一个技能上。

以下是个人常用宏：
#showtooltip
/cast [modifier:alt]寒冰箭(等级 1);寒冰箭
按住ALT来按的话就是1级的寒冰箭，直接按就顶级。

#showtooltip
/cast [modifier:alt]深度冻结;冰枪术
这个参照上面，不解释

#showtooltip
/cast [modifier:alt] 造食术(等级 8)
/use 魔法羊角面包

/use [flyable] 绿色驭风者;紫色骷髅战马
旧大陆骑马，外星就飞飞。

宏的话涉及参数比较多，变化甚多。比如说CASTSEQUENCE这个宏通常用在副本输出，变成无脑输出流，合理搭配上CD技能的话DPS会有很大提升。

第一个感觉没必要 反正又不是战斗中 就多那几秒的操作...无视..

第二个技能太多 还没有手动的快..

请把方向键改成rdfg剩下的n多键位你慢慢设置，要红干什么