vb中计算器的编码怎么写 请又能力的 把各个按钮的的代码 都写给我

' ------------------------------------------------------------------------
' 版权所有 (C) 1994 Microsoft Corporation
'
' 您可以免费以任何方式使用、修改、复制并分发您认为有用的
' 示例应用程序文件 (或任何修改过的版本)。Microsoft 对任何
' 示例应用程序文件不做任何保证，不负任何责任和义务。
' ------------------------------------------------------------------------
Option Explicit
Dim Op1, Op2 ' 预先输入操作数。
Dim DecimalFlag As Integer ' 小数点存在吗？
Dim NumOps As Integer ' 操作数个数。
Dim LastInput ' 指示上一次按键事件的类型。
Dim OpFlag ' 指示未完成的操作。
Dim TempReadout

' C (取消) 按钮的 Click 事件过程
' 重新设置显示并初始化变量。
Private Sub Cancel_Click()
Readout = Format(0, "0.")
Op1 = 0
Op2 = 0
Form_Load
End Sub

' CE (取消输入) 按钮的 Click 事件过程。
Private Sub CancelEntry_Click()
Readout = Format(0, "0.")
DecimalFlag = False
LastInput = "CE"
End Sub

' 小数点 (.) 按钮的 Click 事件过程
' 如果上一次按键为运算符，初始化 readout 为 "0."；
' 否则显示时追加一个小数点。
Private Sub Decimal_Click()
If LastInput = "NEG" Then
Readout = Format(0, "-0.")
ElseIf LastInput <> "NUMS" Then
Readout = Format(0, "0.")
End If
DecimalFlag = True
LastInput = "NUMS"
End Sub

' 窗体的初始化过程
' 设置所有变量为其初始值。
Private Sub Form_Load()
DecimalFlag = False
NumOps = 0
LastInput = "NONE"
OpFlag = " "
Readout = Format(0, "0.")
'Decimal.Caption = Format(0, ".")
End Sub

' 数字键 (0-9) 的 Click 事件过程
' 向显示中的数追加新数。
Private Sub Number_Click(Index As Integer)
If LastInput <> "NUMS" Then
Readout = Format(0, ".")
DecimalFlag = False
End If
If DecimalFlag Then
Readout = Readout + Number(Index).Caption
Else
Readout = Left(Readout, InStr(Readout, Format(0, ".")) - 1) + Number(Index).Caption + Format(0, ".")
End If
If LastInput = "NEG" Then Readout = "-" & Readout
LastInput = "NUMS"
End Sub

' 运算符 (+, -, x, /, =) 的 Click 事件过程
' 如果接下来的按键是数字键，增加 NumOps。
' 如果有一个操作数，则设置 Op1。
' 如果有两个操作数，则将 Op1 设置为 Op1 与
' 当前输入字符串的运算结果，并显示结果。
Private Sub Operator_Click(Index As Integer)
TempReadout = Readout
If LastInput = "NUMS" Then
NumOps = NumOps + 1
End If
Select Case NumOps
Case 0
If Operator(Index).Caption = "-" And LastInput <> "NEG" Then
Readout = "-" & Readout
LastInput = "NEG"
End If
Case 1
Op1 = Readout
If Operator(Index).Caption = "-" And LastInput <> "NUMS" And OpFlag <> "=" Then
Readout = "-"
LastInput = "NEG"
End If
Case 2
Op2 = TempReadout
Select Case OpFlag
Case "+"
Op1 = CDbl(Op1) + CDbl(Op2)
Case "-"
Op1 = CDbl(Op1) - CDbl(Op2)
Case "X"
Op1 = CDbl(Op1) * CDbl(Op2)
Case "/"
If Op2 = 0 Then
MsgBox "除数不能为零", 48, "计算器"
Else
Op1 = CDbl(Op1) / CDbl(Op2)
End If
Case "="
Op1 = CDbl(Op2)
Case "%"
Op1 = CDbl(Op1) * CDbl(Op2)
End Select
Readout = Op1
NumOps = 1
End Select
If LastInput <> "NEG" Then
LastInput = "OPS"
OpFlag = Operator(Index).Caption
End If
End Sub

' 百分比键 (%) 的 Click 事件过程
' 计算并显示第一个操作数的百分数。
Private Sub Percent_Click()
Readout = Readout / 100
LastInput = "Ops"
OpFlag = "%"
NumOps = NumOps + 1
DecimalFlag = True
End Sub

切，这都不会。
把各个按钮的代码都给你，不行。
但是我可以给你关键代码。
此函数用于计算四则运算算式（带括号，不支持小数），例如：
Dim R&
lEval "1+2*3/(4+2)", R
然后R的值为2

Function lEVal(ByVal Expression$, VOut&) As Boolean
Dim I&, Ret&, J&, Mide$
I = InStrRev(Expression, "(")
While I
I = I + 1
For J = I To Len(Expression) + 1
If I >= Len(Expression) + 1 Then Exit Function
If Mid(Expression, J, 1) = ")" Then Exit For
Next
Mide = Mid(Expression, I, J - I)
If Not Ekh(Mide, Ret) Then Exit Function
Expression = Replace(Expression, "(" & Mide & ")", Ret)
I = InStrRev(Expression, "(")
Wend
If Not Ekh(Expression, VOut) Then Exit Function
lEVal = True
End Function

Private Function Ekh(ByVal Expre$, Ret&) As Boolean
Dim I&, J&, L&, R&, U$, Re&
Expre = Replace(Expre, " ", "")
Expre = Replace(Expre, "/", "\")
For I = 1 To Len(Expre)
Re = Asc(Mid(Expre, I, 1))
If (Re < 48 Or Re > 57) And Re <> 42 And Re <> 92 And Re <> 45 And Re <> 43 Then Exit Function
Next
I = InStr(Expre, "*")
While I
If I Then
For J = I - 1 To 1 Step -1
If Not IsNumeric(Mid(Expre, J, 1)) Then Exit For
Next
J = J + 1
L = Val(Mid(Expre, J))
R = Val(Mid(Expre, I + 1))
Re = L * R
U = L & "*" & R
Expre = Replace(Expre, U, Re)
End If
I = InStr(Expre, "*")
Wend
I = InStr(Expre, "\")
While I
If I Then
For J = I - 1 To 1 Step -1
If Not IsNumeric(Mid(Expre, J, 1)) Then Exit For
Next
J = J + 1
L = Val(Mid(Expre, J))
R = Val(Mid(Expre, I + 1))
Re = L \ R
U = L & "\" & R
Expre = Replace(Expre, U, Re)
End If
I = InStr(Expre, "\")
Wend
I = InStr(Expre, "+")
While I
If I Then
For J = I - 1 To 1 Step -1
If Not IsNumeric(Mid(Expre, J, 1)) Then Exit For
Next
J = J + 1
L = Val(Mid(Expre, J))
R = Val(Mid(Expre, I + 1))
Re = L + R
U = L & "+" & R
Expre = Replace(Expre, U, Re)
End If
I = InStr(Expre, "+")
Wend
I = InStr(Expre, "-")
While I
If I Then
For J = I - 1 To 1 Step -1
If Not IsNumeric(Mid(Expre, J, 1)) Then Exit For
Next
J = J + 1
L = Val(Mid(Expre, J))
R = Val(Mid(Expre, I + 1))
Re = L - R
U = L & "-" & R
Expre = Replace(Expre, U, Re)
End If
I = InStr(Expre, "-")
Wend
Re = Val(Expre)
If Len(CStr(Re)) <> Len(Expre) Then Exit Function
Ret = Re
Ekh = True
End Function

Private Sub Command1_Click()
If Text2.Text = "+" Or Text2.Text = "-" Or Text2.Text = "*" Or Text2.Text = "/" Then
Select Case Text2.Text
Case "+"
Text4.Text = Val(Val(Text1.Text)) + Val(Text3.Text)
Case "-"
Text4.Text = Val(Text1.Text) - Val(Text3.Text)
Case "*"
Text4.Text = Val(Text1.Text) * Val(Text3.Text)
Case "/"
If Val(Text3.Text) = "0" Then
MsgBox "被除数不能为零！"
Else
Text4.Text = Val(Text1.Text) / Val(Text3.Text)
End If
End Select
Else
MsgBox "您的运算符输入不正确！"
End If
End Sub

楼主朋友，你好啊
我是六年级的小豆包，我自编了一个最简单的计算器：
Private Sub Command1_Click()
Text3.Text = Val(Text1.Text) + Val(Text2.Text)
End Sub

Private Sub Command2_Click()
Text3.Text = Val(Text1.Text) - Val(Text2.Text)
End Sub

Private Sub Command3_Click()
Text3.Text = Val(Text1.Text) * Val(Text2.Text)
End Sub

Private Sub Command4_Click()
Text3.Text = Val(Text1.Text) / Val(Text2.Text)
End Sub

Private Sub Command5_Click()
Text1.Text = ""
Text2.Text = ""
Text3.Text = ""
End Sub

Private Sub Command6_Click()
End
End Sub
没有参考的，自己做的最最简单的一个，还可以吧
如果你要图的话，跟我说好啦
要实物的话，也跟我说好啦
不明白的话，还是跟我说啊。。。
谢谢啦，爱花_twilight

这是我昨晚做的Dim op1 As Byte

Dim ops1, ops2

Dim res As Boolean

Private Sub Command3_Click()

ops2 = Val(Label1.Caption)

Select Case op1

Case 0

  Label1.Caption = ops1 + ops2

Case 1

  Label1.Caption = ops1 - ops2

Case 2

  Label1.Caption = ops1 * ops2

Case Else

  Label1.Caption = ops1 / ops2

End Select

End Sub

Private Sub Command4_Click()

Label1.Caption = ""

End Sub

Private Sub Form_Load()

res = False

End Sub

Private Sub numble_Click(i1 As Integer)

If Not res Then

Label1.Caption = Label1.Caption & i1

Else

Label1.Caption = i1

End If

res = False

End Sub

Private Sub operator_Click(i2 As Integer)

res = True

ops1 = Val(Label1.Caption)

op1 = i2

Label1.Caption = ""

End Sub